सामग्रीहरू
- एक्सेलमा VLOOKUP प्रकार्य - सामान्य विवरण र वाक्य रचना
- VLOOKUP उदाहरणहरू
- VLOOKUP प्रकार्यमा सटीक वा अनुमानित मिल्दो
- एक्सेलमा VLOOKUP - तपाईंले यो याद गर्न आवश्यक छ!
आज हामी एक्सेल - को सबैभन्दा उपयोगी सुविधाहरू मध्ये एक वर्णन गर्ने लेखहरूको श्रृंखला सुरु गर्दैछौं VPR (VLOOKUP)। यो प्रकार्य, एकै समयमा, सबैभन्दा जटिल र कम बुझिएको मध्ये एक हो।
यस ट्यूटोरियल मा VPR अनुभवहीन प्रयोगकर्ताहरूका लागि सिक्ने प्रक्रियालाई सकेसम्म स्पष्ट बनाउनको लागि म आधारभूत कुराहरू सकेसम्म सरल रूपमा राख्ने प्रयास गर्नेछु। थप रूपमा, हामी एक्सेल सूत्रहरूसँग धेरै उदाहरणहरू अध्ययन गर्नेछौं जसले प्रकार्यको लागि सबैभन्दा सामान्य प्रयोग केसहरू प्रदर्शन गर्नेछ VPR.
एक्सेलमा VLOOKUP प्रकार्य - सामान्य विवरण र वाक्य रचना
त्यसैले यो के हो VPR? खैर, सबै भन्दा पहिले, यो एक एक्सेल प्रकार्य हो। के गर्छिन् ? यसले तपाईँले निर्दिष्ट गरेको मान हेर्छ र अर्को स्तम्भबाट सम्बन्धित मान फर्काउँछ। प्राविधिक रूपमा भन्नुपर्दा, VPR दिइएको दायराको पहिलो स्तम्भमा मान हेर्छ र उही पङ्क्तिको अर्को स्तम्भबाट परिणाम फर्काउँछ।
सबैभन्दा सामान्य अनुप्रयोगमा, प्रकार्य VPR दिइएको अद्वितीय पहिचानकर्ताको लागि डाटाबेस खोज्छ र डाटाबेसबाट यससँग सम्बन्धित केही जानकारी निकाल्छ।
प्रकार्यको नाममा पहिलो अक्षर VPR (VLOOKUP) को अर्थ Вठाडो (Vठाडो)। यसबाट तपाईं छुट्याउन सक्नुहुन्छ VPR बाट GPR (HLOOKUP), जसले दायरा − को शीर्ष पङ्क्तिमा मान खोज्छ Гतेर्सो (Hतेर्सो)।
समारोह VPR Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP, र Excel 2000 मा उपलब्ध छ।
VLOOKUP प्रकार्यको सिन्ट्याक्स
समारोह VPR (VLOOKUP) मा निम्न वाक्य रचना छ:
VLOOKUP(lookup_value,table_array,col_index_num,[range_lookup])
ВПР(искомое_значение;таблица;номер_столбца;[интервальный_просмотр])
तपाईं देख्न सक्नुहुन्छ, एक प्रकार्य VPR Microsoft Excel मा 4 विकल्पहरू (वा तर्कहरू) छन्। पहिलो तीन अनिवार्य छन्, अन्तिम वैकल्पिक छ।
- look_value (lookup_value) - हेर्नको लागि मान। यो मान (नम्बर, मिति, पाठ) वा सेल सन्दर्भ (लुकअप मान सहित), वा कुनै अन्य एक्सेल प्रकार्य द्वारा फिर्ता गरिएको मान हुन सक्छ। उदाहरण को लागी, यो सूत्र मान को लागी हेर्नेछ 40:
=VLOOKUP(40,A2:B15,2)
=ВПР(40;A2:B15;2)
यदि लुकअप मान दायराको पहिलो स्तम्भमा सबैभन्दा सानो मान भन्दा कम छ भने, प्रकार्य VPR त्रुटि रिपोर्ट गर्नेछ #AT (#N/A)।
- टेबल_अरे (तालिका) - डाटाको दुई वा बढी स्तम्भहरू। सम्झनुहोस्, समारोह VPR सधैँ तर्कमा दिइएको दायराको पहिलो स्तम्भमा मान खोज्छ टेबल_अरे (तालिका)। हेर्न सकिने दायराले विभिन्न डेटा समावेश गर्न सक्छ, जस्तै पाठ, मिति, संख्या, बुलियन। प्रकार्य केस असंवेदनशील छ, यसको अर्थ माथिल्लो र सानो अक्षरहरू समान मानिन्छ। त्यसैले हाम्रो सूत्रले मूल्य खोज्नेछ 40 बाट कक्षहरूमा A2 लाई A15, किनभने A तर्कमा दिइएको दायरा A2:B15 को पहिलो स्तम्भ हो टेबल_अरे (तालिका):
=VLOOKUP(40,A2:B15,2)
=ВПР(40;A2:B15;2)
- col_index_num (column_number) दिइएको दायरामा रहेको स्तम्भको संख्या हो जसबाट फेला पारिएको पङ्क्तिको मान फर्काइनेछ। दिइएको दायरामा सबैभन्दा बायाँ स्तम्भ हो 1, दोस्रो स्तम्भ हो 2, तेस्रो स्तम्भ हो 3 र यस्तै। अब तपाइँ सम्पूर्ण सूत्र पढ्न सक्नुहुन्छ:
=VLOOKUP(40,A2:B15,2)
=ВПР(40;A2:B15;2)
सूत्र मूल्य खोज्दै 40 दायरामा A2:A15 र स्तम्भ B बाट सम्बन्धित मान फर्काउँछ (किनभने B दायरा A2:B15 मा दोस्रो स्तम्भ हो)।
यदि तर्कको मूल्य हो col_index_num (column_number) भन्दा कम 1त्यसपछि VPR त्रुटि रिपोर्ट गर्नेछ #VALUE! (#VALUE!) र यदि यो दायरामा स्तम्भहरूको संख्या भन्दा बढी छ टेबल_अरे (तालिका), प्रकार्यले त्रुटि फर्काउनेछ #REF! (#LINK!)
- दायरा_लुकअप (range_lookup) - के खोज्ने भनेर निर्धारण गर्दछ:
- सटीक मिलान, तर्क बराबर हुनुपर्छ गलत (FALSE);
- अनुमानित मिलान, तर्क बराबर सही कोड (TRUE) वा निर्दिष्ट गरिएको छैन।
यो प्यारामिटर वैकल्पिक छ, तर धेरै महत्त्वपूर्ण छ। पछि यो ट्यूटोरियल मा VPR सटीक र अनुमानित मिल्दोहरू फेला पार्नका लागि सूत्रहरू कसरी लेख्ने भनेर व्याख्या गर्ने केही उदाहरणहरू देखाउनेछु।
VLOOKUP उदाहरणहरू
म समारोह को आशा गर्दछु VPR तपाईलाई अलिकति स्पष्ट हुनुहोस्। अब केही प्रयोग केसहरू हेरौं VPR वास्तविक डेटाको साथ सूत्रहरूमा।
अर्को एक्सेल पानामा खोजी गर्न VLOOKUP कसरी प्रयोग गर्ने
अभ्यासमा, कार्यको साथ सूत्रहरू VPR एउटै कार्यपत्रमा डाटा खोज्न विरलै प्रयोग गरिन्छ। धेरै पटक होइन, तपाईले अर्को पानाबाट सम्बन्धित मानहरू खोज्दै र पुन: प्राप्त गर्नुहुनेछ।
प्रयोग गर्न VPR, अर्को माइक्रोसफ्ट एक्सेल पानामा खोज्नुहोस्, तपाईंले तर्कमा हुनुपर्छ टेबल_अरे (तालिका) सेलहरूको दायरा पछि विस्मयादिबोधक चिन्हको साथ पानाको नाम निर्दिष्ट गर्नुहोस्। उदाहरणका लागि, निम्न सूत्रले दायरा देखाउँछ A2: B15 नामको पानामा छ पाना २.
=VLOOKUP(40,Sheet2!A2:B15,2)
=ВПР(40;Sheet2!A2:B15;2)
निस्सन्देह, पाना नाम म्यानुअल रूपमा प्रविष्ट गर्न आवश्यक छैन। केवल सूत्र टाइप गर्न सुरु गर्नुहोस्, र जब यो तर्कमा आउँछ टेबल_अरे (तालिका), इच्छित पानामा स्विच गर्नुहोस् र माउसको साथ कक्षहरूको इच्छित दायरा चयन गर्नुहोस्।
तलको स्क्रिनसटमा देखाइएको सूत्रले कार्यपत्रमा स्तम्भ A (यो दायरा A1:B1 को पहिलो स्तम्भ हो) मा "उत्पादन 2" पाठ खोज्छ। मूल्य.
=VLOOKUP("Product 1",Prices!$A$2:$B$9,2,FALSE)
=ВПР("Product 1";Prices!$A$2:$B$9;2;ЛОЖЬ)
कृपया याद गर्नुहोस् कि पाठ मान खोज्दा, तपाईले यसलाई उद्धरण चिन्ह ("") मा संलग्न गर्नुपर्छ, जस्तै सामान्यतया एक्सेल सूत्रहरूमा गरिन्छ।
तर्क को लागी टेबल_अरे (तालिका) सधैं निरपेक्ष सन्दर्भहरू प्रयोग गर्न वांछनीय छ ($ चिन्हको साथ)। यस अवस्थामा, अन्य कक्षहरूमा सूत्र प्रतिलिपि गर्दा खोज दायरा अपरिवर्तित रहनेछ।
VLOOKUP को साथ अर्को कार्यपुस्तिकामा खोज्नुहोस्
कार्य गर्न VPR दुई एक्सेल कार्यपुस्तिकाहरू बीच काम गरेको छ, तपाईंले पानाको नाम अघि वर्ग कोष्ठकमा कार्यपुस्तिका नाम निर्दिष्ट गर्न आवश्यक छ।
उदाहरणका लागि, तल एउटा सूत्र हो जुन मान खोज्छ 40 पानामा पाना २ पुस्तकमा Numbers.xlsx:
=VLOOKUP(40,[Numbers.xlsx]Sheet2!A2:B15,2)
=ВПР(40;[Numbers.xlsx]Sheet2!A2:B15;2)
यहाँ Excel मा एक सूत्र सिर्जना गर्न सजिलो तरिका हो VPRजसले अर्को कार्यपुस्तिकामा लिङ्क गर्दछ:
- दुवै किताब खोल्नुहोस्। यो आवश्यक छैन, तर यस तरिकाले सूत्र सिर्जना गर्न सजिलो छ। तपाईं कार्यपुस्तिका नाम म्यानुअल रूपमा प्रविष्ट गर्न चाहनुहुन्न, के तपाईं? थप रूपमा, यसले तपाईंलाई आकस्मिक टाइपोबाट बचाउनेछ।
- प्रकार्य टाइप गर्न सुरु गर्नुहोस् VPRर जब यो तर्क को लागी आउँछ टेबल_अरे (तालिका), अर्को कार्यपुस्तिकामा स्विच गर्नुहोस् र यसमा आवश्यक खोज दायरा चयन गर्नुहोस्।
तलको स्क्रिनसटले कार्यपुस्तिकाको दायरामा खोजी सेट गरिएको सूत्र देखाउँछ PriceList.xlsx पानामा मूल्य.
समारोह VPR तपाईँले खोजी कार्यपुस्तिका बन्द गर्दा पनि काम गर्नेछ र तल देखाइए अनुसार कार्यपुस्तिका फाइलको पूर्ण मार्ग सूत्र पट्टीमा देखिन्छ:
यदि कार्यपुस्तिका वा पानाको नाममा खाली ठाउँहरू छन् भने, यसलाई अपोस्ट्रोफहरूमा संलग्न हुनुपर्छ:
=VLOOKUP(40,'[Numbers.xlsx]Sheet2'!A2:B15,2)
=ВПР(40;'[Numbers.xlsx]Sheet2'!A2:B15;2)
VLOOKUP सँग सूत्रहरूमा नामित दायरा वा तालिका कसरी प्रयोग गर्ने
यदि तपाइँ धेरै प्रकार्यहरूमा एउटै खोज दायरा प्रयोग गर्ने योजना बनाउनुहुन्छ VPR, तपाईले नामित दायरा सिर्जना गर्न सक्नुहुन्छ र तर्कको रूपमा सूत्रमा यसको नाम प्रविष्ट गर्न सक्नुहुन्छ टेबल_अरे (तालिका)।
नामित दायरा सिर्जना गर्न, केवल कक्षहरू चयन गर्नुहोस् र फिल्डमा उपयुक्त नाम प्रविष्ट गर्नुहोस् नाम, सूत्र पट्टीको बायाँतिर।
अब तपाईले उत्पादनको मूल्य पत्ता लगाउन निम्न सूत्र लेख्न सक्नुहुन्छ उत्पाद 1:
=VLOOKUP("Product 1",Products,2)
=ВПР("Product 1";Products;2)
धेरै दायरा नामहरूले सम्पूर्ण एक्सेल कार्यपुस्तिकाको लागि काम गर्दछ, त्यसैले त्यहाँ तर्कको लागि पाना नाम निर्दिष्ट गर्न आवश्यक छैन। टेबल_अरे (तालिका), सूत्र र खोज दायरा फरक कार्यपत्रहरूमा भए तापनि। यदि तिनीहरू फरक कार्यपुस्तिकाहरूमा छन् भने, त्यसपछि दायराको नाम अघि तपाईंले कार्यपुस्तिकाको नाम निर्दिष्ट गर्न आवश्यक छ, उदाहरणका लागि, यो जस्तै:
=VLOOKUP("Product 1",PriceList.xlsx!Products,2)
=ВПР("Product 1";PriceList.xlsx!Products;2)
त्यसैले सूत्र धेरै स्पष्ट देखिन्छ, सहमत हुनुहुन्छ? साथै, नामित दायराहरू प्रयोग गर्नु निरपेक्ष सन्दर्भहरूको लागि राम्रो विकल्प हो किनभने तपाईंले अन्य कक्षहरूमा सूत्र प्रतिलिपि गर्दा नामित दायरा परिवर्तन हुँदैन। यसको मतलब यो हो कि तपाईं पक्का हुन सक्नुहुन्छ कि सूत्रमा खोज दायरा सधैं सही रहनेछ।
यदि तपाइँ आदेश प्रयोग गरेर कक्षहरूको दायरालाई पूर्ण एक्सेल स्प्रेडसिटमा रूपान्तरण गर्नुहुन्छ तालिका (तालिका) ट्याब सम्मिलन (घुसाउनुहोस्), त्यसपछि जब तपाइँ माउसको साथ दायरा चयन गर्नुहुन्छ, Microsoft Excel ले स्वचालित रूपमा सूत्रमा स्तम्भ नामहरू (वा यदि तपाइँ सम्पूर्ण तालिका चयन गर्नुहुन्छ भने तालिकाको नाम) थप्नेछ।
समाप्त सूत्र यस्तो केहि देखिनेछ:
=VLOOKUP("Product 1",Table46[[Product]:[Price]],2)
=ВПР("Product 1";Table46[[Product]:[Price]];2)
वा सायद यो जस्तै:
=VLOOKUP("Product 1",Table46,2)
=ВПР("Product 1";Table46;2)
नामित दायराहरू प्रयोग गर्दा, लिङ्कहरूले एउटै कक्षहरूमा संकेत गर्नेछन्, तपाईंले कार्यलाई जहाँ पनि प्रतिलिपि गर्नुभयो VPR कार्यपुस्तिका भित्र।
VLOOKUP सूत्रहरूमा वाइल्डकार्डहरू प्रयोग गर्दै
अन्य धेरै कार्यहरू जस्तै, VPR तपाइँ निम्न वाइल्डकार्ड वर्णहरू प्रयोग गर्न सक्नुहुन्छ:
- प्रश्न चिन्ह (?) - कुनै एकल वर्ण प्रतिस्थापन गर्दछ।
- Asterisk (*) - वर्णहरूको कुनै पनि अनुक्रम प्रतिस्थापन गर्दछ।
प्रकार्यहरूमा वाइल्डकार्डहरू प्रयोग गर्दै VPR धेरै अवस्थामा उपयोगी हुन सक्छ, उदाहरणका लागि:
- जब तपाइँ ठ्याक्कै याद गर्नुहुन्न पाठ तपाइँ फेला पार्न आवश्यक छ।
- जब तपाइँ केहि शब्द फेला पार्न चाहानुहुन्छ जुन सेलको सामग्रीको अंश हो। त्यो थाहा छ VPR सम्पूर्ण रूपमा कक्षको सामग्रीहरूद्वारा खोजी गर्दछ, मानौं विकल्प सक्षम पारिएको छ सम्पूर्ण सेल सामग्री मिलाउनुहोस् मानक एक्सेल खोजमा (सम्पूर्ण सेल)।
- जब सेलले सामग्रीको सुरु वा अन्त्यमा अतिरिक्त खाली ठाउँहरू समावेश गर्दछ। यस्तो अवस्थामा, तपाईं आफ्नो दिमाग लामो समयसम्म र्याक गर्न सक्नुहुन्छ, सूत्र किन काम गर्दैन भनेर पत्ता लगाउन प्रयास गर्दै।
उदाहरण 1: निश्चित वर्णहरूसँग सुरु वा अन्त्य हुने पाठ खोज्दै
मानौं तपाईं तल देखाइएको डाटाबेसमा एक विशिष्ट ग्राहक खोज्न चाहनुहुन्छ। तपाईंलाई उसको अन्तिम नाम याद छैन, तर तपाईंलाई थाहा छ कि यो "ack" बाट सुरु हुन्छ। यहाँ एक सूत्र छ जसले काम राम्रो गर्नेछ:
=VLOOKUP("ack*",$A$2:$C$11,1,FALSE)
=ВПР("ack*";$A$2:$C$11;1;ЛОЖЬ)
अब जब तपाइँ निश्चित हुनुहुन्छ कि तपाइँ सही नाम फेला पार्नुभयो, तपाइँ यो ग्राहक द्वारा भुक्तान गरिएको रकम फेला पार्न उही सूत्र प्रयोग गर्न सक्नुहुन्छ। यो गर्नको लागि, केवल प्रकार्यको तेस्रो तर्क परिवर्तन गर्नुहोस् VPR इच्छित स्तम्भ नम्बरमा। हाम्रो अवस्थामा, यो स्तम्भ C (दायरामा तेस्रो):
=VLOOKUP("ack*",$A$2:$C$11,3,FALSE)
=ВПР("ack*";$A$2:$C$11;3;ЛОЖЬ)
यहाँ वाइल्डकार्डका केही उदाहरणहरू छन्:
~ "मानिस" मा अन्त्य हुने नाम खोज्नुहोस्:
=VLOOKUP("*man",$A$2:$C$11,1,FALSE)
=ВПР("*man";$A$2:$C$11;1;ЛОЖЬ)
~ एउटा नाम खोज्नुहोस् जुन "विज्ञापन" बाट सुरु हुन्छ र "छोरा" बाट समाप्त हुन्छ:
=VLOOKUP("ad*son",$A$2:$C$11,1,FALSE)
=ВПР("ad*son";$A$2:$C$11;1;ЛОЖЬ)
~ हामी सूचीमा पहिलो नाम फेला पार्छौं, 5 वर्णहरू समावेश:
=VLOOKUP("?????",$A$2:$C$11,1,FALSE)
=ВПР("?????";$A$2:$C$11;1;ЛОЖЬ)
कार्य गर्न VPR वाइल्डकार्डहरूले सही रूपमा काम गर्यो, चौथो तर्कको रूपमा तपाईंले सधैं प्रयोग गर्नुपर्छ गलत (FALSE)। यदि खोज दायरामा एक भन्दा बढी मानहरू छन् जुन वाइल्डकार्डहरूसँग खोज शब्दहरूसँग मेल खान्छ, त्यसपछि फेला परेको पहिलो मान फिर्ता गरिनेछ।
उदाहरण २: VLOOKUP सूत्रहरूमा वाइल्डकार्डहरू र सेल सन्दर्भहरू जोड्नुहोस्
अब हामी कसरी प्रकार्य प्रयोग गरेर खोजी गर्ने बारे थोरै जटिल उदाहरण हेरौं VPR सेल मा मूल्य द्वारा। कल्पना गर्नुहोस् कि स्तम्भ A लाइसेन्स कुञ्जीहरूको सूची हो, र स्तम्भ B नामहरूको सूची हो जुन इजाजतपत्रको स्वामित्वमा छ। थप रूपमा, तपाईंसँग सेल C1 मा कुनै प्रकारको इजाजतपत्र कुञ्जीको अंश (धेरै क्यारेक्टरहरू) छ, र तपाईं मालिकको नाम फेला पार्न चाहनुहुन्छ।
यो निम्न सूत्र प्रयोग गरेर गर्न सकिन्छ:
=VLOOKUP("*"&C1&"*",$A$2:$B$12,2,FALSE)
=ВПР("*"&C1&"*";$A$2:$B$12;2;FALSE)
यो सूत्रले दिइएको दायरामा सेल C1 बाट मान खोज्छ र स्तम्भ B बाट सम्बन्धित मान फर्काउँछ। ध्यान दिनुहोस् कि पहिलो तर्कमा, हामी पाठ स्ट्रिङ लिङ्क गर्न सेल सन्दर्भ अघि र पछि एम्परसेन्ड (&) क्यारेक्टर प्रयोग गर्छौं।
तपाईले तलको चित्रमा देख्न सक्नुहुन्छ, प्रकार्य VPR "जेरेमी हिल" फर्काउँछ किनभने उसको इजाजतपत्र कुञ्जीले सेल C1 बाट क्यारेक्टरहरूको अनुक्रम समावेश गर्दछ।
ध्यान दिनुहोस् कि तर्क टेबल_अरे (तालिका) माथिको स्क्रिनसटमा कक्षहरूको दायरा निर्दिष्ट गर्नुको सट्टा तालिका (तालिका7) को नाम समावेश छ। यो हामीले अघिल्लो उदाहरणमा के गर्यौं।
VLOOKUP प्रकार्यमा सटीक वा अनुमानित मिल्दो
र अन्तमा, कार्यको लागि निर्दिष्ट गरिएको अन्तिम तर्कमा नजिकबाट हेरौं VPR - दायरा_लुकअप (interval_view)। पाठको सुरुमा उल्लेख गरिएझैं यो तर्क धेरै महत्त्वपूर्ण छ। तपाईं यसको मूल्यको साथ एउटै सूत्रमा पूर्ण रूपमा फरक परिणामहरू प्राप्त गर्न सक्नुहुन्छ सही कोड (TRUE) वा गलत (FALSE)।
पहिले, सही र अनुमानित मेलहरू द्वारा माइक्रोसफ्ट एक्सेलको अर्थ के हो भनेर पत्ता लगाउनुहोस्।
- यदि तर्क दायरा_लुकअप (range_lookup) बराबर छ गलत (FALSE), सूत्रले ठ्याक्कै मिल्दोजुल्दो खोज्छ, अर्थात् तर्कमा दिइएको ठ्याक्कै उही मान look_value (lookup_value)। यदि दायराको पहिलो स्तम्भमा tसक्षम_एरे (तालिका) ले तर्कसँग मेल खाने दुई वा बढी मानहरू भेट्छ look_value (search_value), त्यसपछि पहिलो चयन गरिनेछ। यदि कुनै मिल्दो भेटिएन भने, प्रकार्यले त्रुटि रिपोर्ट गर्नेछ #AT (#N/A)। उदाहरणका लागि, निम्न सूत्रले त्रुटि रिपोर्ट गर्नेछ #AT (#N/A) दायरा A2:A15 मा कुनै मान छैन भने 4:
=VLOOKUP(4,A2:B15,2,FALSE)
=ВПР(4;A2:B15;2;ЛОЖЬ)
- यदि तर्क दायरा_लुकअप (range_lookup) बराबर छ सही कोड (TRUE), सूत्रले अनुमानित मिलान खोज्छ। थप स्पष्ट रूपमा, पहिले प्रकार्य VPR एक सटीक मिल्दो खोज्छ, र यदि कुनै पनि फेला परेन भने, अनुमानित एक चयन गर्दछ। अनुमानित मिलान सबैभन्दा ठूलो मान हो जुन तर्कमा तोकिएको मानभन्दा बढी हुँदैन। look_value (lookup_value)।
यदि तर्क दायरा_लुकअप (range_lookup) बराबर छ सही कोड (TRUE) वा तोकिएको छैन, त्यसपछि दायराको पहिलो स्तम्भमा भएका मानहरूलाई बढ्दो क्रममा क्रमबद्ध गरिनुपर्छ, अर्थात् सबैभन्दा सानोदेखि ठूलोसम्म। अन्यथा, समारोह VPR गलत परिणाम फर्काउन सक्छ।
छनोटको महत्त्व राम्रोसँग बुझ्नको लागि सही कोड (सत्य) वा गलत (FALSE), प्रकार्यसँग केही थप सूत्रहरू हेरौं VPR र परिणामहरू हेर्नुहोस्।
उदाहरण 1: VLOOKUP सँग सटीक मिलान खोज्दै
तपाईलाई याद छ, सटीक मिलान खोज्नको लागि, प्रकार्यको चौथो तर्क VPR फरक पर्छ गलत (FALSE)।
पहिलो उदाहरणबाट तालिकामा फर्कौं र कुन जनावरले गतिमा जान सक्छ भनेर पत्ता लगाउनुहोस् 50 माइल प्रति घण्टा। मलाई विश्वास छ कि यो सूत्रले तपाईंलाई कुनै पनि कठिनाइहरू ल्याउने छैन:
=VLOOKUP(50,$A$2:$B$15,2,FALSE)
=ВПР(50;$A$2:$B$15;2;ЛОЖЬ)
ध्यान दिनुहोस् कि हाम्रो खोज दायरा (स्तम्भ A) मा दुई मानहरू छन् 50 - कक्षहरूमा A5 и A6। सूत्रले कक्षबाट मान फर्काउँछ B5। किन? किनभने सटीक मिलान खोज्दा, प्रकार्य VPR फेला परेको पहिलो मान प्रयोग गर्दछ जुन खोजिएकोसँग मेल खान्छ।
उदाहरण २: अनुमानित मिल्दो पत्ता लगाउन VLOOKUP प्रयोग गर्दै
जब तपाइँ प्रकार्य प्रयोग गर्नुहुन्छ VPR अनुमानित मिलान खोज्नको लागि, जस्तै जब तर्क दायरा_लुकअप (range_lookup) बराबर छ सही कोड (TRUE) वा मेटाइयो, तपाईंले गर्नु पर्ने पहिलो कुरा आरोही क्रममा पहिलो स्तम्भद्वारा दायरा क्रमबद्ध गर्नु हो।
यो धेरै महत्त्वपूर्ण छ किनभने समारोह VPR दिइएको एक पछि अर्को सबैभन्दा ठूलो मान फर्काउँछ, र त्यसपछि खोज रोकिन्छ। यदि तपाईंले सही क्रमबद्धतालाई बेवास्ता गर्नुभयो भने, तपाईं धेरै अनौठो परिणाम वा त्रुटि सन्देशको साथ समाप्त हुनुहुनेछ। #AT (#N/A)।
अब तपाइँ निम्न सूत्रहरू मध्ये एक प्रयोग गर्न सक्नुहुन्छ:
=VLOOKUP(69,$A$2:$B$15,2,TRUE)
or =VLOOKUP(69,$A$2:$B$15,2)
=ВПР(69;$A$2:$B$15;2;ИСТИНА)
or =ВПР(69;$A$2:$B$15;2)
तपाईले देख्न सक्नुहुन्छ, म कुन जनावरको सबैभन्दा नजिकको गति छ भनेर पत्ता लगाउन चाहन्छु 69 माइल प्रति घण्टा। र यहाँ परिणाम छ समारोह मलाई फर्काइयो VPR:
तपाईं देख्न सक्नुहुन्छ, सूत्र परिणाम फर्काइयो एन्टेलोप (मृग), जसको गति 61 माइल प्रति घण्टा, यद्यपि सूचीमा पनि समावेश छ चीता (चित्ता) जो गतिमा दौडिन्छ 70 माइल प्रति घण्टा, र 70 69 भन्दा 61 को नजिक छ, हैन? यो किन भइरहेको छ? किनभने समारोह VPR अनुमानित मिलान खोज्दा, खोजीएको भन्दा ठूलो नभई सबैभन्दा ठूलो मान फर्काउँछ।
मलाई आशा छ कि यी उदाहरणहरूले प्रकार्यसँग काम गर्नमा केही प्रकाश पार्छ VPR Excel मा, र तपाईंले अब उसलाई बाहिरी व्यक्तिको रूपमा हेर्नुहुन्न। अब यसलाई मेमोरीमा राम्रोसँग ठीक गर्नको लागि हामीले अध्ययन गरेका सामग्रीका मुख्य बुँदाहरू संक्षिप्त रूपमा दोहोर्याउन चोट लाग्दैन।
एक्सेलमा VLOOKUP - तपाईंले यो याद गर्न आवश्यक छ!
- समारोह VPR एक्सेल बायाँ हेर्न सक्दैन। यसले सधैँ तर्कद्वारा दिइएको दायराको सबैभन्दा बायाँ स्तम्भमा मान खोज्छ टेबल_अरे (तालिका)।
- समारोहमा VPR सबै मानहरू केस-संवेदनशील छन्, अर्थात् साना र ठूला अक्षरहरू बराबर छन्।
- यदि तपाईले खोज्नु भएको मान दायराको पहिलो स्तम्भमा रहेको न्यूनतम मान भन्दा कम छ भने, प्रकार्य VPR त्रुटि रिपोर्ट गर्नेछ #AT (#N/A)।
- यदि तेस्रो तर्क col_index_num (column_number) भन्दा कम 1समारोह VPR त्रुटि रिपोर्ट गर्नेछ #VALUE! (#VALUE!) यदि यो दायरामा स्तम्भहरूको संख्या भन्दा ठूलो छ टेबल_अरे (तालिका), प्रकार्यले त्रुटि रिपोर्ट गर्नेछ #REF! (#LINK!)
- तर्कमा निरपेक्ष कक्ष सन्दर्भहरू प्रयोग गर्नुहोस् टेबल_अरे (तालिका) ताकि सूत्र प्रतिलिपि गर्दा सही खोज दायरा सुरक्षित हुन्छ। एक विकल्पको रूपमा Excel मा नामित दायरा वा तालिकाहरू प्रयोग गर्ने प्रयास गर्नुहोस्।
- अनुमानित मिल्दो खोज गर्दा, तपाईंले खोजिरहनु भएको दायरामा पहिलो स्तम्भलाई बढ्दो क्रममा क्रमबद्ध गरिनु पर्छ भनेर याद गर्नुहोस्।
- अन्तमा, चौथो तर्कको महत्त्व सम्झनुहोस्। मानहरू प्रयोग गर्नुहोस् सही कोड (सत्य) वा गलत (FALSE) जानाजानी र तपाईले धेरै टाउको दुखाइबाट छुटकारा पाउनुहुनेछ।
हाम्रो प्रकार्य ट्यूटोरियलको निम्न लेखहरूमा VPR Excel मा, हामी थप उन्नत उदाहरणहरू सिक्ने छौं, जस्तै प्रयोग गरेर विभिन्न गणनाहरू प्रदर्शन गर्ने VPR, बहु स्तम्भहरूबाट मानहरू निकाल्दै, र थप। यो ट्यूटोरियल पढ्नुभएकोमा धन्यवाद र म तपाईंलाई अर्को हप्ता फेरि भेट्ने आशा गर्दछु!